Capteur d’humidité et de température

/*
  Rui Santos
  Complete project details at https://RandomNerdTutorials.com/esp8266-nodemcu-mqtt-publish-dht11-dht22-arduino/
  
  Permission is hereby granted, free of charge, to any person obtaining a copy
  of this software and associated documentation files.
  
  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.
  type de carte : esp8266 generic
*/

#include "DHT.h"   // librairie pour gérer le DHT 11 (et autres)
#include <ESP8266WiFi.h> // librairie pour se connecter au wifi
#include <Ticker.h> // librairie pour appeler des fonctions avec des répétitions, délais, etc...
#include <AsyncMqttClient.h> // librairie pour publier en MQTT

#define WIFI_SSID "********"  // remplacer avec le nom de votre réseau wifi 2.4 Ghz
#define WIFI_PASSWORD "********" // remplacer avec le mot de passe du réseau wifi

// Raspberri Pi Mosquitto MQTT Broker
#define MQTT_HOST IPAddress(192, 168, 10, 120) // adresse de votre MQTT Broker
// For a cloud MQTT broker, type the domain name
//#define MQTT_HOST "example.com"
#define MQTT_PORT 1883 // Port à changer si vous n'utilisez pas le port par défaut

// Temperature MQTT Topics
#define MQTT_PUB_TEMP "esp/dht/hangar1/temperature" // à adapter en fonction de votre organisation des pubs MQTT
#define MQTT_PUB_HUM "esp/dht/hangar1/humidity" // à adapter en fonction de votre organisation des pubs MQTT

// Digital pin connected to the DHT sensor / Pin digital connecté au senseur DHT
#define DHTPIN 5 // Attention, à ne pas confondre la nomination du PIN ex : D0 et le numéro GPIO. Il me semble qu'on peut utiliser la nomination complète ex : D0

// Uncomment whatever DHT sensor type you're using // Décommenter le senseur que vous utilisez et commenter les autres. Là, c'est le DHT11 qui sera utilisé
#define DHTTYPE DHT11   // DHT 11
//#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)   

// Initialize DHT sensor / Permet d'initialiser le DHT
DHT dht(DHTPIN, DHTTYPE);

// Variables to hold sensor readings / Valeurs pour enregistrer les valeurs du senseur
float temp;
float hum;

AsyncMqttClient mqttClient; 
Ticker mqttReconnectTimer;

WiFiEventHandler wifiConnectHandler;
WiFiEventHandler wifiDisconnectHandler;
Ticker wifiReconnectTimer;

unsigned long previousMillis = 0;   // Stores last time temperature was published / Permet de garder la dernière fois où la température a été publiée
const long interval = 10000;        // Interval at which to publish sensor readings / Intervalle de publication ex 10s en ms : 10 000

void connectToWifi() {
  Serial.println("Connecting to Wi-Fi..."); // Connection au wifi
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
}

void onWifiConnect(const WiFiEventStationModeGotIP& event) {
  Serial.println("Connected to Wi-Fi."); // Connection réussie
  connectToMqtt();
}

void onWifiDisconnect(const WiFiEventStationModeDisconnected& event) {
  Serial.println("Disconnected from Wi-Fi."); // Disconnecté du wifi
  mqttReconnectTimer.detach(); // ensure we don't reconnect to MQTT while reconnecting to Wi-Fi / assure que nous n'essayons pas de nous reconnecter au MQTT pendant la reconnection au wifi
  wifiReconnectTimer.once(2, connectToWifi);
}

void connectToMqtt() {
  Serial.println("Connecting to MQTT..."); // Connection au MQTT Broker
  mqttClient.connect();
}

void onMqttConnect(bool sessionPresent) {
  Serial.println("Connected to MQTT."); // Connecté !
  Serial.print("Session present: ");
  Serial.println(sessionPresent);
}

void onMqttDisconnect(AsyncMqttClientDisconnectReason reason) {
  Serial.println("Disconnected from MQTT."); // Disconnecté du MQTT

  if (WiFi.isConnected()) {
    mqttReconnectTimer.once(2, connectToMqtt);
  }
}

/*void onMqttSubscribe(uint16_t packetId, uint8_t qos) {
  Serial.println("Subscribe acknowledged.");
  Serial.print("  packetId: ");
  Serial.println(packetId);
  Serial.print("  qos: ");
  Serial.println(qos);
}

void onMqttUnsubscribe(uint16_t packetId) {
  Serial.println("Unsubscribe acknowledged.");
  Serial.print("  packetId: ");
  Serial.println(packetId);
}*/

void onMqttPublish(uint16_t packetId) {
  Serial.print("Publish acknowledged.");
  Serial.print("  packetId: ");
  Serial.println(packetId);
}

void setup() {
  Serial.begin(115200);
  Serial.println();

  dht.begin();
  
  wifiConnectHandler = WiFi.onStationModeGotIP(onWifiConnect);
  wifiDisconnectHandler = WiFi.onStationModeDisconnected(onWifiDisconnect);

  mqttClient.onConnect(onMqttConnect);
  mqttClient.onDisconnect(onMqttDisconnect);
  //mqttClient.onSubscribe(onMqttSubscribe);
  //mqttClient.onUnsubscribe(onMqttUnsubscribe);
  mqttClient.onPublish(onMqttPublish);
  mqttClient.setServer(MQTT_HOST, MQTT_PORT);
  // If your broker requires authentication (username and password), set them below
  //mqttClient.setCredentials("IoT", "IoT2021"); //Si votre MQTT nécessite un utilisateur et mot de passe
  
  connectToWifi();
}

void loop() {
  unsigned long currentMillis = millis();
  // Every X number of seconds (interval = 10 seconds)
  // it publishes a new MQTT message
  if (currentMillis - previousMillis >= interval) {
    // Save the last time a new reading was published
    previousMillis = currentMillis;
    // New DHT sensor readings
    hum = dht.readHumidity();
    // Read temperature as Celsius (the default)
    temp = dht.readTemperature();
    // Read temperature as Fahrenheit (isFahrenheit = true)
    //temp = dht.readTemperature(true);
    
    // Publish an MQTT message on topic esp/dht/temperature / Publie un message MQTT sur le sujet esp/dht/****/temperature
    uint16_t packetIdPub1 = mqttClient.publish(MQTT_PUB_TEMP, 1, true, String(temp).c_str());                            
    Serial.printf("Publishing on topic %s at QoS 1, packetId: %i ", MQTT_PUB_TEMP, packetIdPub1);
    Serial.printf("Message: %.2f \n", temp);

    // Publish an MQTT message on topic esp/dht/humidity/ Publie un message MQTT sur le sujet esp/dht/****/humidity
    uint16_t packetIdPub2 = mqttClient.publish(MQTT_PUB_HUM, 1, true, String(hum).c_str());                            
    Serial.printf("Publishing on topic %s at QoS 1, packetId %i: ", MQTT_PUB_HUM, packetIdPub2);
    Serial.printf("Message: %.2f \n", hum);
  }
}